home *** CD-ROM | disk | FTP | other *** search
/ FM Towns: Free Software Collection 6 / FM Towns Free Software Collection 6.iso / t_os / yspred / tester.bas < prev    next >
Encoding:
BASIC Source File  |  1993-07-08  |  1.7 KB  |  55 lines
  1. 1000 CLS:DEFINT A-Z:DIM DF(64),CH(64,4),PL(16)
  2. 1010 DEF FNR$(A$)=RIGHT$(A$,1)+LEFT$(A$,1)  'Intel形式に変換するため
  3. 1020 ON ERROR GOTO *ERRTRAP
  4. 1030 '
  5. 1040 PRINT "ファイル名を入力してください":PRINT "＞";
  6. 1050 LINE INPUT F$:IF INSTR(F$,".")=0 THEN F$=F$+".YSP"
  7. 1060 OPEN "I",#1,F$
  8. 1070 '
  9. 1080 A$=INPUT$(2,#1):CHS=CVI(FNR$(A$))      'CHS キャラクター数
  10. 1090 FOR I=0 TO CHS-1                       '↓キャラクターデータ読込
  11. 1100   LOCATE 0,0:PRINT USING "CHARACTOR:####";CHS-I;
  12. 1110   A$=INPUT$(8,#1)
  13. 1120   FOR J=0 TO 3
  14. 1130     CH(I,J)=CVI(FNR$(MID$(A$,J*2+1,2)))
  15. 1140   NEXT
  16. 1150 NEXT                                   '↑キャラクターデータ読込
  17. 1160 '
  18. 1170 A$=INPUT$(2,#1):PLT=CVI(FNR$(A$))      'PLT パレット数
  19. 1180 FOR I=0 TO PLT-1                       '↓パレットデータ読込
  20. 1190   LOCATE 0,0:PRINT USING "PALETTE  :####";PLT-I;
  21. 1200   A$=INPUT$(32,#1)
  22. 1210   FOR J=0 TO 15
  23. 1220     PL(J)=CVI(FNR$(MID$(A$,J*2+1,2)))
  24. 1230   NEXT
  25. 1240   DEF SPRITE 2,I,PL
  26. 1250 NEXT                                   '↑パレットデータ読込
  27. 1260 '
  28. 1270 A$=INPUT$(2,#1):PTN=CVI(FNR$(A$))      'PTN パターン数
  29. 1280 FOR I=0 TO PTN-1
  30. 1290   LOCATE 0,0:PRINT USING "PATTERN  :####";PTN-I;
  31. 1300   A$=INPUT$(128,#1)
  32. 1310   FOR J=0 TO 63
  33. 1320     DF(J)=CVI(FNR$(MID$(A$,J*2+1,2)))
  34. 1330   NEXT
  35. 1340   DEF SPRITE 0,I,DF,0
  36. 1350 NEXT
  37. 1360 CLOSE
  38. 1370 '
  39. 1380 *TESTMAIN
  40. 1390 SCREEN@ 1:SPRITE ON                     'キャラクター定義
  41. 1400 J=0
  42. 1410 FOR I=0 TO CHS-1
  43. 1420   DEF SPRITE 1,J,(40,40),CH(I,0),CH(I,1),CH(I,2),0,CH(I,3)
  44. 1430   J=J+CH(I,1)*CH(I,2)
  45. 1440 NEXT
  46. 1450 '
  47. 1460 J=0
  48. 1470 FOR I=0 TO CHS-1
  49. 1480   SPRITE 0,J,1:A$=INPUT$(1):SPRITE 0,J,0
  50. 1490   J=J+CH(I,1)*CH(I,2)
  51. 1500 NEXT
  52. 1510 GOTO 1460
  53. 1520 *ERRTRAP
  54. 1530 CLOSE:END
  55.